雖然建議在每個Perl腳本和模塊中開啟警告，可是你又不想用戶看到Perl發出的警告。
一方面你想在代碼前面使用use warnings作為你的安全網，另一方面，通常警告會出現在屏幕上。多數情況下，客戶不知道如何處理這些警告。如果幸運的話這些警告僅僅讓客戶驚訝一下，當然，不幸的是他們嘗試著去修復它們... （這里說的不是Perl程序員。）
第三方面，你或許想要保存這些警告供之后分析。
此外，在很多地方還有很多Perl腳本和應用程序沒有使用use warnings也沒有在#!行中使用-w。加上了use warnings就可能會產生大量的警告。
長遠來看，當然是要消除這些警告，但是短期來說呢？
即便是長期計劃，你也不能寫出完全沒有BUG的代碼，你也不能確保應用將來永遠不會打印出警告信息。
你能么？
你可以在警告打印到屏幕之前捕獲它們。
信號
Perl有一個叫做%SIG的內建hash表，其中的鍵是操作系統信號的名字。對應的值是函數（大多數是函數引用），這些函數會在特定的信號觸發時被調用。
除了系統提供的標準信號以外，Perl還添加了兩個內部“信號”。其中一個是h__warn__ span="">，它在每次代碼調用warn()函數的時候觸發。另外一個是__DIE__，它在每次調用die()時觸發。
在本文中，我們會看到這些是怎樣影響警告信息的。
匿名函數
sub { }是匿名函數，也就是一個只有函數體而沒有名字的函數。（在這個例子中函數體也是空的，但是我希望你能明白我的意思。）
捕獲警告--不處理
如果添加如下代碼：
復制代碼 代碼如下:
local $SIG{__WARN__} = sub {
# 此處可以獲得警告信息
};
這實際上表示每次程序的某個地方產生了警告信息時，不做任何處理。基本上，這會隱藏所有的警告。
捕獲警告--并轉換成異常
You could also write: 你也可以寫成：
復制代碼 代碼如下:
local $SIG{__WARN__} = sub {
die;
};
這樣會在每次產生警告的時候調用die()，也就是把每個警告轉換成異常。
如果你想在異常中包含警告信息，可以這么寫：
復制代碼 代碼如下:
local $SIG{__WARN__} = sub {
my $message = shift;
die $message;
};
實際的警告信息會作為唯一的參數傳遞給匿名函數。
捕獲警告--并寫入日志
你可能想在中間做些其他事情：
過濾嘈雜的警告信息，留待后來分析：
復制代碼 代碼如下:
local $SIG{__WARN__} = sub {
my $message = shift;
logger($message);
};
這里我們假設logger()是你實現的寫日志函數。
寫日志
假設你的應用程序已經有日志機制。如果沒有的話，最好加上。即便你不能添加，你也需要操作系統的內建日志機制。例如Linux的syslog，MS Windows的Event Logger，其它操作系統也有它們內部的日志機制。
在本文的例子里，我們使用一個自制logger()函數來代表這個想法。
捕獲并寫日志的完整例子
復制代碼 代碼如下:
#!/usr/bin/perl
use strict;
use warnings;
local $SIG{__WARN__} = sub {
my $message = shift;
logger('warning', $message);
};
my $counter;
count();
print "$counter\n";
sub count {
$counter = $counter + 42;
}
sub logger {
my ($level, $msg) = @_;
if (open my $out, '>>', 'log.txt') {
chomp $msg;
print $out "$level - $msg\n";
}
}
上面的代碼會在log.txt文件中添加下面一行：
復制代碼 代碼如下:
Use of uninitialized value in addition (+) at code_with_warnings.pl line 14.
變量$counter和函數count()僅是產生警告示例的一部分。
警告處理函數中的警告信息
__WARN__在其處理函數執行過程中是自動被禁用的。所以在警告處理函數執行過程中產生的（新）警告信息不會導致無限循環。
你可以在perlvar文檔中了解到更多細節。
Avoid multiple warnings
需要注意的是重復的警告信息可能會充斥日志文件。我可以使用一個簡單的類似緩存的特性來減少重復警告信息的數量。
復制代碼 代碼如下:
#!/usr/bin/perl
use strict;
use warnings;
my %WARNS;
local $SIG{__WARN__} = sub {
my $message = shift;
return if $WARNS{$message}++;
logger('warning', $message);
};
my $counter;
count();
print "$counter\n";
$counter = undef;
count();
sub count {
$counter = $counter + 42;
}
sub logger {
my ($level, $msg) = @_;
if (open my $out, '>>', 'log.txt') {
chomp $msg;
print $out "$level - $msg\n";
}
}
可以看到，我們把$counter變量賦值成undef，然后再次調用count()函數來產生同樣的警告。
我們也把__WARN__的處理函數替換成一個稍微復雜的版本：
復制代碼 代碼如下:
my %WARNS;
local $SIG{__WARN__} = sub {
my $message = shift;
return if $WARNS{$message}++;
logger('warning', $message);
};
在調用logger之前，會檢查一下當前字符串是否已經在%WARNShash表中。如果沒有的話，會添加它并調用logger()。如果已經有了，就調用return，并不二次記錄同樣的事件。
你可能回憶起我們在unique values in an array也使用了同樣的點子。
local是什么？
在上面所有的例子中，我使用local函數來局部化（警告處理）效果。嚴格來說，在這些例子中我們沒有必要這么做，因為假設這些代碼是主腳本的第一部分。這種情況下就無所謂了，畢竟是在全局作用域里面。
然而，最好是這么用。
local對于在模塊中限制（對警告）的改變是很重要的。特別是要發布的模塊。如果沒有局部化，會影響整個應用程序。limit則會把影響限制在所在的閉合代碼塊里。
避免使用全局的%WARNS
如果你正在使用Perl 5.10或者更新的版本，你可以改寫一下代碼來替換掉全局變量%WARNS。要這么做的話，需在腳本的開頭使用use v5.10;，然后在匿名函數內部使用state關鍵詞來聲明變量。
復制代碼 代碼如下:
#!/usr/bin/perl
use strict;
use warnings;
use v5.10;
local $SIG{__WARN__} = sub {
state %WARNS;
my $message = shift;
return if $WARNS{$message}++;
logger('warning', $message);
};
