公司運(yùn)營(yíng)著的網(wǎng)站，流量很大，網(wǎng)站是交互式的，經(jīng)常在過(guò)了三四個(gè)月的時(shí)候索引生成的碎片就很多，由于很大一部分頁(yè)面沒(méi)有生成靜態(tài)，這就導(dǎo)致網(wǎng)站在打開(kāi)的速度上會(huì)變慢。
以前都是手工右擊索引重新生成，但是索引太多，操作起來(lái)費(fèi)時(shí)費(fèi)力，索引在網(wǎng)上找了個(gè)存儲(chǔ)過(guò)程，自己整理了一下，執(zhí)行的時(shí)候只需要選擇相應(yīng)的數(shù)據(jù)庫(kù)，運(yùn)行exec sp_rebuild_index即可，如下。
USE [master]
GO
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
CREATE proc [dbo].[sp_rebuild_index]
(
@Rebuild_Fragmentation_Percent smallint = 5 -- 當(dāng)邏輯碎片百分比 > 5% 重新生成索引
)
as
begin
/* 調(diào)用方法：
1.針對(duì)當(dāng)前實(shí)例所有數(shù)據(jù)庫(kù)： exec sys.sp_MSforeachdb 'use ?;exec sp_rebuild_index'
2.針對(duì)當(dāng)前數(shù)據(jù)庫(kù)： exec sp_rebuild_index
*/
--對(duì)系統(tǒng)數(shù)據(jù)庫(kù)不作重新組織索引和重新生成索引
if (db_name() in ('master','model','msdb','tempdb')) return;
--如果邏輯碎片（索引中的無(wú)序頁(yè)）的百分比 = 5% ，就不作重新組織索引和重新生成索引
if not exists(select 1 from sys.dm_db_index_physical_stats(db_id(),null,null,null,null) a where a.index_id>0 and a.avg_fragmentation_in_percent > @Rebuild_Fragmentation_Percent) return
print replicate('-',60)+char(13)+char(10)+replicate(' ',14)+N'對(duì)數(shù)據(jù)庫(kù) '+quotename(db_name())+N' 進(jìn)行索引優(yōu)化'+replicate(' ',20)+char(13)+char(10)
declare @sql nvarchar(2000),@str nvarchar(2000)
declare cur_x cursor for
select 'alter index '+quotename(a.name)+' on '+quotename(object_schema_name(a.object_id))+'.'+quotename(object_name(a.object_id))+' rebuild;' as [sql]
,N'重新生成索引：' +quotename(object_schema_name(a.object_id))+'.'+quotename(object_name(a.object_id))+'.'+quotename(a.name) as [str]
from sys.indexes a
inner join sys.dm_db_index_physical_stats(db_id(),null,null,null,null) b on b.object_id=a.object_id
and b.index_id=a.index_id
where a.index_id>0
and b.avg_fragmentation_in_percent > @Rebuild_Fragmentation_Percent
order by object_name(a.object_id),a.index_id
open cur_x
fetch next from cur_x into @sql,@str
while (@@fetch_status = 0)
begin
print @sql
exec(@sql)
print @str
fetch next from cur_x into @sql,@str
end
close cur_x
deallocate cur_x
end
