成人激情视频,欧美亚洲动漫制服丝袜,欧美不卡视频

主頁 > 知識庫 > 批處理完美實現FTP遠程備份數據

批處理完美實現FTP遠程備份數據

經過再次努力，終于完成了自己的比較滿意的版本，大家多批評……

批處理功能：

輸入幾個參數，讓批處理代你完成煩瑣的工作吧！遠程FTP文件到本地計算機，你可以拖入開機啟動或任務計劃中，定時下載遠程的指定數據，希望大家多測試，多提意見，多完善，謝謝！上代碼！

舉例說明：

我需要每天早上從服務器202.33.22.102上下載指定目錄的文件到本機，那么你需要指定以下幾個參數即可

一、遠程IP，Is not null

二、FTP用戶名,Is not null

三、遠程密碼,Is not null

四、下載哪個目錄下的文件，如果是根目錄則輸入點點，即".."(沒有雙引號)

五、子目錄，你可能要下載一個文件夾下的多個目錄吧？如果有，請用逗號隔開，如果沒有則什么也不要設置(包括空格)，文件夾名請間量不要有空格，以免不必要的麻煩，當你指定了子目錄時，程序只會下載該子目錄下的文件，而對再下一級文件夾不做任何操作。

六、本地目錄，請指定一個已存在的目錄，包括"\"，程序會自動在該文件夾下創建和服務器上相同的文件夾

七、日志記錄文件目錄，也是已存在的。

好了，你現在可以雙擊這個批處理執行操作了！

@echo off
echo ********====================================================== 
echo ********====================================================== 
echo ++++++++  批處理功能： 遠程數據FTP備份到本地
echo ++++++++  Date:  %Date:~0,4%-%Date:~5,2%-%Date:~8,2% 
echo ++++++++  Author:  zc_0101         
echo ++++++++  Email:  zc_0101@163.com
echo ++++++++  QQ：  275374095
echo ++++++++  Mark:
echo ++++++++    請嚴格按照參數說明定義參數，輸入參數
echo ++++++++    請盡量常規化，不要帶特殊字符包括空格
echo ++++++++    如果文件已存在則跳過，不支持短點續傳
echo ++++++++    不檢測備份數據完整性，用戶可自行修改
echo ++++++++  PS:  轉載請注明出處(^_^),謝謝！
echo ********====================================================== 
echo ********====================================================== 
pause

Rem 遠程IP(請保證開啟Server_U)
Set Remote_IP=103.111.124.123

Rem 遠程登錄用戶名(如果有批處理符號，請進行轉義)
Set Remote_User=test

Rem 遠程登錄密碼(如果有批處理符號，請進行轉義)
Set Remote_Pwd=FkhVBweos^!Sd4al%%

Rem 遠程操作目錄,如果是根目錄，請填寫".."(無雙引號),否則直接填寫目錄名,如Databaseback
set Remote_Path=Databaseback 

Rem 遠程要下載的目錄列表(注意:僅下載這些目錄下的文件，不會下載子目錄下的文件)，請用逗號隔開,如果沒有子目錄（確保當前目錄下有文件可下載），請什么也不要填寫(包括空格);另：文件夾請不要有空格
Set Remote_Directory=DB_Hxxl,DB_OA,master,model,msdb 

Rem 本地備份目錄，請填寫一個已存在的目錄(本程序將會自動在該目錄下創建和遠程服務器上同樣的子目錄,請勿帶"\"斜杠)
Set Local_Path=D:\DBback

Rem 操作日志和臨時文件存放路徑(請務必帶上"\"斜杠)
Set Log_Path=D:\


Rem 取得當前日期，作為日志文件名稱,本例為日志存放目錄加當日日期
set today="%Log_Path%%Date:~0,4%-%Date:~5,2%-%Date:~8,2%-%Time:~0,2%%Time:~3,2%%Time:~6,2%.txt"
echo 正在對您輸入的參數進行基本檢測…………
echo 正在檢測輸入參數…………>%today%
if "%Remote_IP%" EQU "" (
  echo 遠程IP不能為空！請返回為Remote_IP賦值
  echo 遠程IP為空，程序退出。>>%today%
  pause
  exit
)
if "%Remote_User%" EQU "" (
  echo 遠程登錄名不能為空！請返回為Remote_User賦值
  echo 遠程登錄名為空，程序退出。>>%today%
  pause
  exit
)
if "%Remote_Pwd%" EQU "" (
  echo 遠程登錄密碼不能為空！請返回為Remote_Pwd賦值
  echo 遠程登錄密碼為空，程序退出。>>%today%
  pause
  exit
)
if "%Remote_Path%" EQU "" (
  echo 遠程操作目錄不能為空！請返回為Remote_Path賦值,如果是對根目錄操作，請輸入^(點點^)，即".."
  echo 遠程操作目錄為空，程序退出。>>%today%
  pause
  exit
)
if "%Remote_Directory%" EQU " " (
  echo 遠程子目錄有誤！您是否為Remote_Directory誤賦值為空格了？如果沒有子目錄請不要賦值，包括空格。
  echo 遠程子目錄有誤，程序退出。>>%today%
  pause
  exit
)
if "%Local_Path%\" EQU "" (
  echo 本地操作目錄不能為空！請返回為Local_Path賦值 
  echo 本地操作目錄為空，程序退出。>>%today%
  pause
  exit
)
if "%Log_Path%" EQU "" (
  echo 本地日志存放目錄不能為空！請返回為Log_Path賦值 
  echo 本地日志存放目錄為空，程序退出。>>%today%
  pause
  exit
)
echo 參數基本檢測通過，準備執行數據庫備份
echo 參數基本檢測通過，數據庫備份現在開始>>%today%
echo 今天是%Date%,時間是：%Time:~0,2%:%Time:~3,2%:%Time:~6,2%,正在執行數據庫備份…………
echo 今天是%Date%,時間是：%Time:~0,2%:%Time:~3,2%:%Time:~6,2%,正在執行數據庫備份…………>>%today%

echo 正在創建生成文件列表的ftp文件，請稍候………
echo 正在創建生成文件列表的ftp文件，請稍候…………>>%today%
ping -n 3 127.1>nul

echo 正在將遠程登錄用戶名寫入ftp文件…………>>%today%
echo %Remote_User%>%Log_Path%command.txt
echo 正在將遠程登錄密碼寫入ftp文件…………>>%today%
echo %Remote_Pwd%>>%Log_Path%command.txt
echo 正在將下載方式寫入ftp文件…………>>%today%
echo type Binary>>%Log_Path%command.txt
echo 正在判斷遠程父目錄是否為根目錄 …………>>%today%
if "%Remote_Path%" NEQ ".." (
  if "%Remote_Path%" NEQ "" (
    echo 正在將進入遠程目錄%Remote_Path%的語句寫入ftp文件…………>>%today%
    echo cd %Remote_Path%>>%Log_Path%command.txt
  )
)
echo 正在判斷遠程子目錄…………>>%today%
if "%Remote_Directory%" NEQ "" (
  echo 正在將子目錄列表的生成語句寫入ftp文件…………>>%today%
  for %%i in (%Remote_Directory%) do (
     echo 正在將子目錄列表%%i的生成語句寫入ftp文件…………>>%today%
     echo mls %%i %Log_Path%%%i_temp.txt>>%Log_Path%command.txt
  )
) else (
  echo 由于沒有填寫子目錄，則將根目錄下文件列表的生成語句寫入ftp文件…………>>%today%
  echo mls - %Log_Path%FileList_temp.txt>>%Log_Path%command.txt
  
) 
echo close>>%Log_Path%command.txt 
echo quit>>%Log_Path%command.txt
echo 正在對command.txt文件進行判斷
if not exist "%Log_Path%command.txt\" (
  if exist "%Log_Path%command.txt" (
    echo %Log_Path%command.txt文件創建成功
    echo %Log_Path%command.txt文件創建成功>>%today%
  ) else (
    echo %Log_Path%command.txt文件創建失敗，程序將退出。
    echo %Log_Path%command.txt文件創建失敗，程序退出>>%today%
    pause
    echo exit
  )
) else (
  echo 您輸入的參數存放日志路徑中有竟然有一個名為Command.txt的文件夾，請手動刪除后，重新運行程序。
  echo 您輸入的參數存放日志路徑中竟然有有一個名為Command.txt的文件夾,程序退出。>>%today%
  pause
  exit
)

echo 正在執行服務器目錄文件列表創建,請稍候…………
echo 正在執行服務器目錄文件列表創建,請稍候…………>>%today%
ping -n 3 127.1>nul
ftp -i -s:%Log_Path%command.txt %Remote_IP%
echo 正在檢查已創建的服務器目錄文件列表，請稍候…………
echo 正在檢查已創建的服務器目錄文件列表，請稍候…………>>%today%
if "%Remote_Directory%" NEQ "" (
  for %%i in (%Remote_Directory%) do (
    if not exist "%Log_Path%%%i.txt\" (
      if exist "%Log_Path%\%%i_temp.txt" (
        mshta "javascript:var fso=new ActiveXObject('Scripting.FileSystemObject');fso.OpenTextFile('%Log_Path%\temp1.txt',2,true).Write(fso.OpenTextFile('%Log_Path%\%%i_temp.txt').ReadAll().replace(/\r\n/g, '\n\n'));close()"
        mshta "javascript:var fso=new ActiveXObject('Scripting.FileSystemObject');fso.OpenTextFile('%Log_Path%\temp2.txt',2,true).Write(fso.OpenTextFile('%Log_Path%\temp1.txt').ReadAll().replace(/\r/g, ''));close()"
        mshta "javascript:var fso=new ActiveXObject('Scripting.FileSystemObject');fso.OpenTextFile('%Log_Path%\%%i.txt',2,true).Write(fso.OpenTextFile('%Log_Path%\temp2.txt').ReadAll().replace(/\n\n/g, '\r\n'));close()"
      )  
      if exist "%Log_Path%%%i.txt" (
        echo %Log_Path%%%i.txt文件創建成功！
        echo %Log_Path%%%i.txt文件創建成功！>>%today%
      ) else (
        echo 對不起，%Log_Path%%%i.txt文件創建失??！程序將退出！
        echo %Log_Path%%%i.txt文件創建失敗！程序終止>>%today%
        pause
        exit      
      )
    ) else (
      echo 您輸入的參數存放日志路徑%Log_Path%中有竟然有一個名為%%i.txt的文件夾，請手動刪除后，重新運行程序。
      echo 您輸入的參數存放日志路徑%Log_Path%中竟然有有一個名為%%i.txt的文件夾,程序退出。>>%today%
      pause
      exit
    )
  )
) else (
  if not exist "%Log_Path%FileList.txt\" (
    if exist "%Log_Path%\FileList_temp.txt" (
      mshta "javascript:var fso=new ActiveXObject('Scripting.FileSystemObject');fso.OpenTextFile('%Log_Path%\temp1.txt',2,true).Write(fso.OpenTextFile('%Log_Path%\FileList_temp.txt').ReadAll().replace(/\r\n/g, '\n\n'));close()"
      mshta "javascript:var fso=new ActiveXObject('Scripting.FileSystemObject');fso.OpenTextFile('%Log_Path%\temp2.txt',2,true).Write(fso.OpenTextFile('%Log_Path%\temp1.txt').ReadAll().replace(/\r/g, ''));close()"
      mshta "javascript:var fso=new ActiveXObject('Scripting.FileSystemObject');fso.OpenTextFile('%Log_Path%\FileList.txt',2,true).Write(fso.OpenTextFile('%Log_Path%\temp2.txt').ReadAll().replace(/\n\n/g, '\r\n'));close()"
    )
    if exist "%Log_Path%FileList.txt" (
    echo %Log_Path%FileList.txt文件創建成功！
      echo %Log_Path%FileList.txt文件創建成功！>>%today%
    ) else (
      echo 對不起，%Log_Path%FileList.txt文件創建失??！
      echo %Log_Path%FileList.txt文件創建失??！程序終止>>%today%
      pause
      exit
    )
  ) else (
    echo 您輸入的參數存放日志路徑%Log_Path%中有竟然有一個名為FileList.txt的文件夾，請手動刪除后，重新運行程序。
    echo 您輸入的參數存放日志路徑%Log_Path%中竟然有有一個名為FileList.txt的文件夾,程序退出。>>%today%
    pause
    exit
  )
)

echo 程序開始下載文件，請耐心等待…………
echo 程序開始下載文件，請耐心等待…………>>%today%
if "%Remote_Directory%" NEQ "" (
  for %%i in (%Remote_Directory%) do (
    echo 正在創建目錄%Local_Path%\%%i…………
    echo 創建目錄%Local_Path%\%%i…………>>%today%
    md %Local_Path%\%%i
    echo 正在下載%Remote_Path%\%%i文件夾備份,請稍候…………
    echo 正在下載%Remote_Path%\%%i文件夾備份,請稍候…………>>%today%
    ping -n 3 127.1>nul
    for /f "delims=. tokens=1,2" %%j in (%Log_Path%%%i.txt) do (
      if not exist "%Local_Path%\%%i\%%j.%%k\" (
        if not exist "%Local_Path%\%%i\%%j.%%k" (
          echo 正在創建下載文件%%j.%%k的腳本,請稍候…………
          echo 正在創建下載文件%%j.%%k的腳本,請稍候…………>>%today%
          echo %Remote_User%>%Log_Path%GetFiles.txt
          echo %Remote_Pwd%>>%Log_Path%GetFiles.txt
          echo type Binary>>%Log_Path%GetFiles.txt
          if "%Remote_Path%" NEQ "" (
            if "%Remote_Path%" NEQ ".." ( 
              echo cd %Remote_Path%>>%Log_Path%GetFiles.txt
            )
          )
          echo cd %%i>>%Log_Path%GetFiles.txt
          echo lcd %Local_Path%\%%i>>%Log_Path%GetFiles.txt
          echo mget "%%j.%%k">>%Log_Path%GetFiles.txt
          echo close>>%Log_Path%GetFiles.txt
          echo quit>>%Log_Path%GetFiles.txt
          ftp -i -s:%Log_Path%GetFiles.txt %Remote_IP%
          echo 正在檢查文件%Local_Path%\%%i\%%j.%%k，請稍候……
          echo 正在檢查文件%Local_Path%\%%i\%%j.%%k，請稍候……>>%today%
          if exist "%Local_Path%\%%i\%%j.%%k\" (
            echo ————下載%Local_Path%\%%i\%%j.%%k成功！
            echo ————下載%Local_Path%\%%i\%%j.%%k成功！>>%today%
          ) else (
            echo ——由于未知原因，下載%Local_Path%\%%i\%%j.%%k失敗！
            echo ——由于未知原因，下載%Local_Path%\%%i\%%j.%%k失??！>>%today%
          )
        ) else (
          echo %Local_Path%\%%i\%%j.%%k已存在，正在跳過————
          echo %Local_Path%\%%i\%%j.%%k已存在，正在跳過————>>%today%
        )
      ) else (
        echo 您輸入的參數存放備份路徑%Local_Path%\%%i中有竟然有一個名為%%j.%%k的文件夾，請手動刪除后，重新運行程序。
        echo 您輸入的參數存放備份路徑%Local_Path%\%%i中竟然有有一個名為%%j.%%k的文件夾,程序退出。>>%today%
        pause
        exit
      )
    )
  )
) else (
  echo 由于沒有指定服務器子目錄，程序將把服務器父目錄下的文件備份到您指定的本地目錄中…………
  echo 由于沒有指定服務器子目錄，程序將把服務器父目錄下的文件備份到您指定的本地目錄中…………>>%today%
  for /f "delims=. tokens=1,2" %%j in (%Log_Path%FileList.txt) do (
    if not exist "%Local_Path%\%%j.%%k\" (
      if not exist "%Local_Path%\%%j.%%k" (
        echo 正在創建下載文件%%j.%%k的腳本,請稍候…………
        echo 正在創建下載文件%%j.%%k的腳本,請稍候…………>>%today%
        echo %Remote_User%>%Log_Path%GetFiles.txt
        echo %Remote_Pwd%>>%Log_Path%GetFiles.txt
        echo type Binary>>%Log_Path%GetFiles.txt
        if "%Remote_Path%" NEQ "" (
          if "%Remote_Path%" NEQ ".." ( 
            echo cd %Remote_Path%>>%Log_Path%GetFiles.txt
          )
        )
        echo lcd %Local_Path%>>%Log_Path%GetFiles.txt
        echo mget "%%j.%%k">>%Log_Path%GetFiles.txt
        echo close>>%Log_Path%GetFiles.txt
        echo quit>>%Log_Path%GetFiles.txt
        ftp -i -s:%Log_Path%GetFiles.txt %Remote_IP%
        echo 正在檢查文件%Local_Path%\%%j.%%k，請稍候……
        echo 正在檢查文件%Local_Path%\%%j.%%k，請稍候……>>%today%
        if exist "%Local_Path%\%%j.%%k" (
          echo ————下載%Local_Path%\%%j.%%k成功！
          echo ————下載%Local_Path%\%%j.%%k成功！>>%today%
        ) else (
          echo ——由于未知原因，下載%Local_Path%\%%j.%%k失??！
          echo ——由于未知原因，下載%Local_Path%\%%j.%%k失??！>>%today%
        )
      ) else (
        echo %Local_Path%\%%j.%%k已存在，正在跳過————
        echo %Local_Path%\%%j.%%k已存在，正在跳過————>>%today%
      )
    ) else (
      echo 您輸入的參數存放備份路徑%Local_Path%\中有竟然有一個名為%%j.%%k的文件夾，請手動刪除后，重新運行程序。
      echo 您輸入的參數存放備份路徑%Local_Path%\中竟然有有一個名為%%j.%%k的文件夾,程序退出。>>%today%
      pause
      exit
    )
  )
)

echo 程序正在清除臨時文件，請稍候…………
set temp_str=command.txt,temp1.txt,temp2.txt,GetFiles.txt
for %%i in (%temp_str%) do (
  echo 程序將刪除%Log_Path%%%i文件…………>>%today%
  del %Log_Path%%%i
  if exist "%Log_Path%%%i" (
    echo %Log_Path%%%i文件刪除失敗，程序繼續運行
    echo %Log_Path%%%i文件刪除失敗，程序繼續運行>>%today%
  ) else (
    echo %Log_Path%%%i文件刪除成功
    echo %Log_Path%%%i文件刪除成功>>%today%
  )
)

echo 程序正在刪除臨時文件列表文件，請稍候…………
echo 程序正在刪除臨時文件列表文件，請稍候…………>>%today%
if "%Remote_Directory%" NEQ "" (
  for %%i in (%Remote_Directory%) do (
    Del %Log_Path%%%i.txt,%Log_Path%%%i_temp.txt
    if exist "%Log_Path%%%i.txt" (
      echo %Log_Path%%%i.txt文件刪除失敗，程序繼續運行
      echo %Log_Path%%%i.txt文件刪除失敗，程序繼續運行>>%today%
    ) else (
      echo %Log_Path%%%i.txt文件刪除成功 
      echo %Log_Path%%%i.txt文件刪除成功 >>%today%
    )
  )
) else (
  del %Log_Path%FileList.txt,%Log_Path%FileList_temp.txt
  if exist "%Log_Path%FileList.txt" (
    echo %Log_Path%FileList.txt文件刪除失敗，程序繼續運行
    echo %Log_Path%FileList.txt文件刪除失敗，程序繼續運行>>%today%
  ) else (
    echo %Log_Path%FileList.txt文件刪除成功
    echo %Log_Path%FileList.txt文件刪除成功>>%today%
  )
)
echo 恭喜您，本次備份工作已經圓滿完成！詳情請查看%today%日志文件！
echo 恭喜您，本次備份工作已經圓滿完成！>>%today%
echo 數據已被備份到%Local_Path%\目錄中。>>%today%
echo 完成時間：%Time:~0,2%:%Time:~3,2%:%Time:~6,2%>>%today%
pause
exit

您可能感興趣的文章:

批處理(ftp)上傳文件到服務器的代碼
批處理向FTP上傳具有指定屬性的文件(增量備份)
批處理下載FTP服務器上指定分鐘數之前的文件
批處理bat下載FTP服務器上指定天數之前的文件
通過批處理修改FTP賬號和密碼
實現FTP整站上傳的批處理代碼
實現FTP整站上傳的批處理代碼
批處理bat下載FTP服務器上某個目錄下的文件

標簽：蕪湖株洲白銀臺州樂山江西公主嶺三門峽

巨人網絡通訊聲明：本文標題《批處理完美實現FTP遠程備份數據》，本文關鍵詞批處理,完美,實現,FTP,遠程,；如發現本文內容存在版權問題，煩請提供相關信息告之我們，我們將及時溝通與處理。本站內容系統采集于網絡，涉及言論、版權與本站無關。

婷婷综合国产,91蜜桃婷婷狠狠久久综合9色 ,九九九九九精品,国产综合av

批處理完美實現FTP遠程備份數據