在最近的項目開發過程中，遇到了Sql server自動分割月的功能需求，這里在網上整理下資料.
1、為何出現自定義分割月的需求
今天梳理一個平臺的所有函數時，發現了一個自定義分割月函數，也就是指定分割月的開始日索引值（可以從1-31閉區間內的任何一個值）來獲取指定日期所對應的分割月數值。這個函數當時是為了解決業務部門獲取非標準月（標準月就是從每個月的第一天到最后一天組成一個完成的標準月份）的統計匯總數據的。例如：如果指定分割月的開始日索引值為5則表示某個月的5號到下個月的4號之間作為一個完整的分割月；同樣地如果指定分割月的開始日索引值為1則表示標準月等等。
我仔細梳理了這個函數進行了重構簡化以及擴展，該自定義分割月函數的實現區別之前寫的SQL Server時間粒度系列----第3節旬、月時間粒度詳解文章中將一個整數值和月份日期相互轉換功能，這個是按照標準月來實現的，雖然思路大致相同，但是并沒有針對之前的月份日期和整數值轉換函數對來進行擴展而是獨立開發新的功能函數。也是為了盡量做到函數功能職責單一性、穩定性、可維護性以及可擴展性。
2、sql server實現自定義分割月功能
自定義分割月功能函數包括兩個標量函數：ufn_SegMonths和ufn_SegMonth2Date。ufn_SegMonths獲取指定的日期在自定義分割月對應的分割月數值；ufn_SegMonth2Date獲取指定一個分割月數值賭對應的月份日期。
sql server 版本的實現T-SQL代碼如下：
IF OBJECT_ID(N'[dbo].[ufn_SegMonths]', 'FN') IS NOT NULL
BEGIN
DROP FUNCTION [dbo].[ufn_SegMonths];
END
GO
--==================================
-- 功能：根據自定義月開始索引值獲取指定日期所在的自定義月數。
-- 說明：自定義分割月數 = 年整數值*100 + 當前所在分割月值。
-- 環境：SQL Server 2005+。
-- 調用：SET @intSegMonths = dbo.fn_SegMonths('2008-01-14', 15)。
-- 創建：XXXX-XX-XX XX:XX-XX:XX XXX 創建函數實現。
-- 修改：XXXX-XX-XX XX:XX-XX:XX XXX XXXXXXXX。
--==================================
CREATE FUNCTION [dbo].[ufn_SegMonths]
(
@dtmDate AS DATETIME -- 日期
,@tntSegStartIndexOfMonth AS INT = 15 -- 自定義分割月開始索引值（1-31)
)
RETURNS INT
AS
BEGIN
IF (@tntSegStartIndexOfMonth = 0 OR @tntSegStartIndexOfMonth >= 32)
BEGIN
SET @tntSegStartIndexOfMonth = 15;
END
DECLARE
@intYears AS INT
,@tntMonth AS TINYINT
,@sntDay AS SMALLINT;
SELECT
@intYears = DATEDIFF(YEAR, '1900-01-01', @dtmDate)
,@tntMonth = DATEPART(MONTH, @dtmDate)
,@sntDay = DATEPART(DAY, @dtmDate);
IF (@sntDay >= @tntSegStartIndexOfMonth)
BEGIN
SET @tntMonth = @tntMonth + 1;
END
IF (@tntMonth > 12)
BEGIN
SELECT
@intYears = @intYears + 1
,@tntMonth = @tntMonth - 12;
END
RETURN @intYears * 100 + @tntMonth;
END
GO
IF OBJECT_ID(N'[dbo].[ufn_SegMonths2Date]', 'FN') IS NOT NULL
BEGIN
DROP FUNCTION [dbo].[ufn_SegMonths2Date];
END
GO
--==================================
-- 功能：獲取自定義分割月數對應的自定義分割月日期。
-- 說明：自定義分割月日期 = 自定義分割月數/100對應的年整數日期“組合”當前所在分割月值。
-- 環境：SQL Server 2005+。
-- 調用：SET @dtmSegMonthDate = dbo.fn_SegMonths2Date(11602)。
-- 創建：XXXX-XX-XX XX:XX-XX:XX XXX 創建函數實現。
-- 修改：XXXX-XX-XX XX:XX-XX:XX XXX XXXXXXXX。;
--==================================
CREATE FUNCTION [dbo].[ufn_SegMonths2Date]
(
@intSegMonths AS INT -- 自定義分割月數
)
RETURNS DATETIME
AS
BEGIN
DECLARE @dtmDefaultBasedate AS DATETIME;
SET @dtmDefaultBasedate = '1900-01-01';
IF ((@intSegMonths IS NULL) OR (@intSegMonths = 0))
BEGIN
RETURN @dtmDefaultBasedate;
END
DECLARE
@intYears AS INT
,@intMonth AS INT;
SELECT
@intYears = @intSegMonths / 100
,@intMonth = @intSegMonths % 100;
RETURN DATEADD(MONTH, @intMonth - 1, DATEADD(YEAR, @intYears, @dtmDefaultBasedate));
END
GO
3、測試驗證效果
針對以上簡單的測試代碼如下：
DECLARE
@dtmStartDate AS DATETIME
,@dtmEndDate AS DATETIME;
SELECT
@dtmStartDate = '2000-01-01'
,@dtmEndDate = '2016-12-31';
SELECT
[T1].*
,[dbo].[ufn_SegMonths2Date]([T1].[SegMonths]) AS SegMonthDate
FROM (
SELECT
[T].[CDate]
,[dbo].[ufn_SegMonths]([T].[CDate], 28) AS SegMonths
FROM (
SELECT
DATEADD(DAY, [Num], @dtmStartDate) AS CDate
FROM
[dbo].[ufn_GetNums](0, DATEDIFF(DAY, @dtmStartDate, @dtmEndDate))
) AS T
WHERE [T].[CDate] BETWEEN '2014-12-01' AND '2016-03-31'
) AS T1
WHERE DATEPART(DAY, [T1].[CDate]) >= 27
GO
效果截圖如下：
注意：以上測試代碼使用了SQL Server數字輔助表的實現這邊文章的內聯表值函數ufn_GetNums。
4、總結語
這次是梳理平臺的功能性函數所進行的重構簡化以及擴展的實現。盡量將日期有關的功能函數梳理出來，便于直接在sql server用戶數據庫中來使用， 也便于BI倉庫中使用。國慶一來已經過去一周，原來打算一周一遍的計劃還是延期啦，再次嚴重檢討自己。
感謝閱讀，希望能幫助到大家，謝謝大家對本站的支持！
您可能感興趣的文章:- SqlServer中如何解決session阻塞問題
- SqlServer 英文單詞全字匹配詳解及實現代碼
- SqlServer編寫數據庫表的操作方式(建庫、建表、修改語句)
- C#訪問SQLServer增刪改查代碼實例
- SqlServer查詢和Kill進程死鎖的語句
- 獲取SqlServer存儲過程定義的三種方法
- SQLServer主鍵和唯一約束的區別
- SqlServer存儲過程實現及拼接sql的注意點
- win2008 r2 服務器php+mysql+sqlserver2008運行環境配置（從安裝、優化、安全等）
- SQLSERVER簡單創建DBLINK操作遠程服務器數據庫的方法
- SqlServer2008誤操作數據(delete或者update)后恢復數據的方法
