因為要返回表對象，無論后續用什么方法返回，都先要聲明全局type；并且，字段變量類型要為object，不能為record：
create or replace type t_test as object(
EMPNO NUMBER(4),
ENAME VARCHAR2(10),
JOB VARCHAR2(9),
SAL NUMBER(7,2)
);
create or replace type t_test_table as table of t_test;
至于返回表對象的方法，目前發現三種：
1、用數組
create or replace function f_test_array(v_deptno in number default null)
return t_test_table
is
v_test t_test_table := t_test_table();
cursor cur is select empno, ename, job, sal from emp where deptno = v_deptno;
begin
for c in cur loop
v_test.extend();
v_test(v_test.count) := t_test(c.empno, c.ename, c.job, c.sal);
end loop;
return v_test;
end;
2、用pipe
create or replace function f_test_pipe(v_deptno in number default null)
return t_test_table PIPELINED
is
v_test t_test_table := t_test_table();
cursor cur is select empno, ename, job, sal from emp where deptno = v_deptno;
begin
for c in cur loop
pipe row(t_test(c.empno, c.ename, c.job, c.sal));
end loop;
return;
end;
這兩種都需要用游標遍歷，得到表對象，性能上估計第2種較高。
3、用collect（不需要游標，代碼相對簡單）
create or replace function f_test_collect(v_deptno in number default null)
return t_test_table
is
v_test t_test_table := t_test_table();
begin
select t_test(empno, ename, job, sal) bulk collect into v_test from emp where deptno = v_deptno;
return v_test;
end;
需要注意的是，select into之前要先把輸出結果對象化：
t_test(empno, ename, job, sal)
否則會報錯：
ORA-00947: 沒有足夠的值(object多字段)
ORA-00932: 數據類型不一致（object單一字段）
而如果直接在plsql塊中declare類型的話，是不需要先對象化輸出結果的。
三種函數定義方式可以測試輸出一樣的結果：
select * from table(f_test_pipe(30));
select * from table(f_test_array(30));
select * from table(f_test_collect(30));
以上就是本文的全部內容，希望對大家的學習有所幫助，也希望大家多多支持腳本之家。
您可能感興趣的文章:- ORACLE 查詢被鎖住的對象，并結束其會話的方法
- 解析Oracle數據庫中的對象集合schema
- oracle查看會話鎖定的所有對象代碼分享
- ORACLE 常用的SQL語法和數據對象
- Oracle使用PL/SQL操作COM對象
- 基于Oracle的面向對象技術入門基礎簡析開發者網絡Oracle
- PHP 5 數據對象 (PDO) 抽象層與 Oracle
- MS-sql 2005拒絕了對對象 ''xxx'' (數據庫 ''xxx''，架構 ''dbo'')的 SELECT 權限的解決方法
- 重新編譯PLSQL中的無效對象或者指定的對象 的方法
- asp sqlserver 執行存儲過程返回記錄集報對象關閉時不允許操作
